ca25a67d0d
# Objective - Fixes #13872 (also mentioned in #17167) ## Solution - Added conditional padding fields to the shader uniform ## Alternatives ### 1- Use a UVec4 Replace the `u32` field in `MyExtension` by a `UVec4` and only use the `x` coordinate. (This was the original approach, but for consistency with the rest of the codebase, separate padding fields seem to be preferred) ### 2- Don't fix it, unlist it While the fix is quite simple, it does muddy the waters a tiny bit due to `quantize_steps` now being a UVec4 instead of a simple u32. We could simply remove this example from the examples that support WebGL2. ## Testing - Ran the example locally on WebGL2 (and native Vulkan) successfully
66 lines
2.1 KiB
WebGPU Shading Language
66 lines
2.1 KiB
WebGPU Shading Language
#import bevy_pbr::{
|
|
pbr_fragment::pbr_input_from_standard_material,
|
|
pbr_functions::alpha_discard,
|
|
}
|
|
|
|
#ifdef PREPASS_PIPELINE
|
|
#import bevy_pbr::{
|
|
prepass_io::{VertexOutput, FragmentOutput},
|
|
pbr_deferred_functions::deferred_output,
|
|
}
|
|
#else
|
|
#import bevy_pbr::{
|
|
forward_io::{VertexOutput, FragmentOutput},
|
|
pbr_functions::{apply_pbr_lighting, main_pass_post_lighting_processing},
|
|
}
|
|
#endif
|
|
|
|
struct MyExtendedMaterial {
|
|
quantize_steps: u32,
|
|
#ifdef SIXTEEN_BYTE_ALIGNMENT
|
|
// Web examples WebGL2 support: structs must be 16 byte aligned.
|
|
_webgl2_padding_8b: u32,
|
|
_webgl2_padding_12b: u32,
|
|
_webgl2_padding_16b: u32,
|
|
#endif
|
|
}
|
|
|
|
@group(3) @binding(100)
|
|
var<uniform> my_extended_material: MyExtendedMaterial;
|
|
|
|
@fragment
|
|
fn fragment(
|
|
in: VertexOutput,
|
|
@builtin(front_facing) is_front: bool,
|
|
) -> FragmentOutput {
|
|
// generate a PbrInput struct from the StandardMaterial bindings
|
|
var pbr_input = pbr_input_from_standard_material(in, is_front);
|
|
|
|
// we can optionally modify the input before lighting and alpha_discard is applied
|
|
pbr_input.material.base_color.b = pbr_input.material.base_color.r;
|
|
|
|
// alpha discard
|
|
pbr_input.material.base_color = alpha_discard(pbr_input.material, pbr_input.material.base_color);
|
|
|
|
#ifdef PREPASS_PIPELINE
|
|
// in deferred mode we can't modify anything after that, as lighting is run in a separate fullscreen shader.
|
|
let out = deferred_output(in, pbr_input);
|
|
#else
|
|
var out: FragmentOutput;
|
|
// apply lighting
|
|
out.color = apply_pbr_lighting(pbr_input);
|
|
|
|
// we can optionally modify the lit color before post-processing is applied
|
|
out.color = vec4<f32>(vec4<u32>(out.color * f32(my_extended_material.quantize_steps))) / f32(my_extended_material.quantize_steps);
|
|
|
|
// apply in-shader post processing (fog, alpha-premultiply, and also tonemapping, debanding if the camera is non-hdr)
|
|
// note this does not include fullscreen postprocessing effects like bloom.
|
|
out.color = main_pass_post_lighting_processing(pbr_input, out.color);
|
|
|
|
// we can optionally modify the final result here
|
|
out.color = out.color * 2.0;
|
|
#endif
|
|
|
|
return out;
|
|
}
|