814f8d1635
# Objective - Update wgpu to 0.13 - ~~Wait, is wgpu 0.13 released? No, but I had most of the changes already ready since playing with webgpu~~ well it has been released now - Also update parking_lot to 0.12 and naga to 0.9 ## Solution - Update syntax for wgsl shaders https://github.com/gfx-rs/wgpu/blob/master/CHANGELOG.md#wgsl-syntax - Add a few options, remove some references: https://github.com/gfx-rs/wgpu/blob/master/CHANGELOG.md#other-breaking-changes - fragment inputs should now exactly match vertex outputs for locations, so I added exports for those to be able to reuse them https://github.com/gfx-rs/wgpu/pull/2704
74 lines
2.0 KiB
WebGPU Shading Language
74 lines
2.0 KiB
WebGPU Shading Language
#import bevy_pbr::mesh_types
|
|
#import bevy_pbr::mesh_view_bindings
|
|
|
|
@group(1) @binding(0)
|
|
var<uniform> mesh: Mesh;
|
|
|
|
// NOTE: Bindings must come before functions that use them!
|
|
#import bevy_pbr::mesh_functions
|
|
|
|
struct Vertex {
|
|
@location(0) position: vec3<f32>,
|
|
@location(1) normal: vec3<f32>,
|
|
@location(2) uv: vec2<f32>,
|
|
};
|
|
|
|
struct VertexOutput {
|
|
@builtin(position) clip_position: vec4<f32>,
|
|
@location(0) uv: vec2<f32>,
|
|
};
|
|
|
|
@vertex
|
|
fn vertex(vertex: Vertex) -> VertexOutput {
|
|
var out: VertexOutput;
|
|
out.clip_position = mesh_position_local_to_clip(mesh.model, vec4<f32>(vertex.position, 1.0));
|
|
out.uv = vertex.uv;
|
|
return out;
|
|
}
|
|
|
|
|
|
struct Time {
|
|
time_since_startup: f32,
|
|
};
|
|
@group(2) @binding(0)
|
|
var<uniform> time: Time;
|
|
|
|
|
|
fn oklab_to_linear_srgb(c: vec3<f32>) -> vec3<f32> {
|
|
let L = c.x;
|
|
let a = c.y;
|
|
let b = c.z;
|
|
|
|
let l_ = L + 0.3963377774 * a + 0.2158037573 * b;
|
|
let m_ = L - 0.1055613458 * a - 0.0638541728 * b;
|
|
let s_ = L - 0.0894841775 * a - 1.2914855480 * b;
|
|
|
|
let l = l_*l_*l_;
|
|
let m = m_*m_*m_;
|
|
let s = s_*s_*s_;
|
|
|
|
return vec3<f32>(
|
|
4.0767416621 * l - 3.3077115913 * m + 0.2309699292 * s,
|
|
-1.2684380046 * l + 2.6097574011 * m - 0.3413193965 * s,
|
|
-0.0041960863 * l - 0.7034186147 * m + 1.7076147010 * s,
|
|
);
|
|
}
|
|
|
|
@fragment
|
|
fn fragment(in: VertexOutput) -> @location(0) vec4<f32> {
|
|
let speed = 2.0;
|
|
let t_1 = sin(time.time_since_startup * speed) * 0.5 + 0.5;
|
|
let t_2 = cos(time.time_since_startup * speed);
|
|
|
|
let distance_to_center = distance(in.uv, vec2<f32>(0.5)) * 1.4;
|
|
|
|
// blending is done in a perceptual color space: https://bottosson.github.io/posts/oklab/
|
|
let red = vec3<f32>(0.627955, 0.224863, 0.125846);
|
|
let green = vec3<f32>(0.86644, -0.233887, 0.179498);
|
|
let blue = vec3<f32>(0.701674, 0.274566, -0.169156);
|
|
let white = vec3<f32>(1.0, 0.0, 0.0);
|
|
let mixed = mix(mix(red, blue, t_1), mix(green, white, t_2), distance_to_center);
|
|
|
|
return vec4<f32>(oklab_to_linear_srgb(mixed), 1.0);
|
|
}
|